build.gradle

import com.vanniktech.maven.publish.SonatypeHost

plugins {
    id 'java'
    id 'signing'
    id 'checkstyle'
    id 'com.vanniktech.maven.publish' version '0.30.0'
}

group = 'io.github.alexshamrai'

repositories {
    mavenCentral()
}

ext {
    projectVersion = '0.3.2-SNAPSHOT'
    releaseVersion = '0.3.1'

    junitVersion = '5.12.2'
    lombokVersion = '1.18.38'
    jaksonVersion = '2.18.3'
    ownerVersion = '1.0.12'
    mockitoVersion = '5.17.0'
    assertjVersion = '3.27.3'

    slf4jVersion = '2.0.17'
    logbackVersion = '1.5.18'
    jacksonModuleJsonSchemaVersion = '2.15.2'
    jsonSchemaValidatorVersion = '2.2.14'
}

version = projectVersion

dependencies {
    implementation platform("org.junit:junit-bom:${junitVersion}")
    implementation "org.junit.jupiter:junit-jupiter-api:${junitVersion}"
    implementation "org.junit.jupiter:junit-jupiter-engine:${junitVersion}"
    implementation "com.fasterxml.jackson.core:jackson-databind:${jaksonVersion}"
    implementation "org.aeonbits.owner:owner:${ownerVersion}"
    compileOnly "org.projectlombok:lombok:${lombokVersion}"
    annotationProcessor "org.projectlombok:lombok:${lombokVersion}"
    testImplementation "org.junit.platform:junit-platform-launcher"
    testImplementation "org.mockito:mockito-core:${mockitoVersion}"
    testImplementation "org.assertj:assertj-core:${assertjVersion}"
}

test {
    useJUnitPlatform()
}

checkstyle {
    toolVersion = '10.23.0'
    configFile = file("${project.rootDir}/config/checkstyle/checkstyle.xml")
}

mavenPublishing {
    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
    signAllPublications()
    coordinates("io.github.alexshamrai", "junit-ctrf-extension", "${releaseVersion}")
    pom {
        name = "Junit CTRF Extension"
        description = "Junit extension to create test reports that follow the CTRF standard."
        inceptionYear = "2024"
        url = "https://github.com/alexshamrai/junit-ctrf-extension"
        licenses {
            license {
                name = "The Apache License, Version 2.0"
                url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                distribution = "http://www.apache.org/licenses/LICENSE-2.0.txt"
            }
        }
        developers {
            developer {
                id = "alexshamrai"
                name = "Oleksii Shamrai"
                url = "https://github.com/alexshamrai/"
            }
        }
        scm {
            url = "https://github.com/alexshamrai/junit-ctrf-extension"
            connection = "scm:git:git://github.com/alexshamrai/junit-ctrf-extension.git"
            developerConnection = "scm:git:ssh://git@github.com/alexshamrai/junit-ctrf-extension.git"
        }
    }
}