-
Notifications
You must be signed in to change notification settings - Fork 3.9k
/
Copy pathrabbit_quorum_queue.erl
1919 lines (1755 loc) · 74.7 KB
/
rabbit_quorum_queue.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% This Source Code Form is subject to the terms of the Mozilla Public
%% License, v. 2.0. If a copy of the MPL was not distributed with this
%% file, You can obtain one at https://mozilla.org/MPL/2.0/.
%%
%% Copyright (c) 2007-2024 Broadcom. All Rights Reserved. The term “Broadcom” refers to Broadcom Inc. and/or its subsidiaries. All rights reserved.
%%
-module(rabbit_quorum_queue).
-behaviour(rabbit_queue_type).
-behaviour(rabbit_policy_validator).
-behaviour(rabbit_policy_merge_strategy).
-export([init/1,
close/1,
update/2,
handle_event/3]).
-export([is_recoverable/1,
recover/2,
stop/1,
start_server/1,
restart_server/1,
stop_server/1,
delete/4,
delete_immediately/1]).
-export([state_info/1, info/2, stat/1, infos/1, infos/2]).
-export([settle/5, dequeue/5, consume/3, cancel/5]).
-export([credit_v1/5, credit/7]).
-export([purge/1]).
-export([stateless_deliver/2, deliver/3]).
-export([dead_letter_publish/5]).
-export([cluster_state/1, status/2]).
-export([update_consumer_handler/8, update_consumer/9]).
-export([cancel_consumer_handler/2, cancel_consumer/3]).
-export([become_leader/2, handle_tick/3, spawn_deleter/1]).
-export([rpc_delete_metrics/1,
key_metrics_rpc/1]).
-export([format/2]).
-export([open_files/1]).
-export([peek/2, peek/3]).
-export([add_member/2,
add_member/3,
add_member/4,
add_member/5]).
-export([delete_member/3, delete_member/2]).
-export([requeue/3]).
-export([policy_changed/1]).
-export([format_ra_event/3]).
-export([cleanup_data_dir/0]).
-export([shrink_all/1,
grow/4,
grow/5]).
-export([transfer_leadership/2, get_replicas/1, queue_length/1]).
-export([file_handle_leader_reservation/1,
file_handle_other_reservation/0]).
-export([file_handle_release_reservation/0]).
-export([list_with_minimum_quorum/0,
list_with_local_promotable/0,
list_with_local_promotable_for_cli/0,
filter_quorum_critical/3,
all_replica_states/0]).
-export([capabilities/0]).
-export([repair_amqqueue_nodes/1,
repair_amqqueue_nodes/2
]).
-export([reclaim_memory/2,
wal_force_roll_over/1]).
-export([notify_decorators/1,
notify_decorators/3,
spawn_notify_decorators/3]).
-export([is_enabled/0,
is_compatible/3,
declare/2,
is_stateful/0]).
-export([validate_policy/1, merge_policy_value/3]).
-export([force_shrink_member_to_current_member/2,
force_all_queues_shrink_member_to_current_member/0]).
-ifdef(TEST).
-export([filter_promotable/2]).
-endif.
-import(rabbit_queue_type_util, [args_policy_lookup/3,
qname_to_internal_name/1,
erpc_call/5]).
-include_lib("stdlib/include/qlc.hrl").
-include_lib("rabbit_common/include/rabbit.hrl").
-include("amqqueue.hrl").
-type msg_id() :: non_neg_integer().
-type qmsg() :: {rabbit_types:r('queue'), pid(), msg_id(), boolean(),
mc:state()}.
-type membership() :: voter | non_voter | promotable. %% see ra_membership() in Ra.
-type replica_states() :: #{atom() => replica_state()}.
-type replica_state() :: leader | follower | non_voter | promotable.
-define(RA_SYSTEM, quorum_queues).
-define(RA_WAL_NAME, ra_log_wal).
-define(STATISTICS_KEYS,
[policy,
operator_policy,
effective_policy_definition,
consumers,
memory,
state,
garbage_collection,
leader,
online,
members,
open_files,
single_active_consumer_pid,
single_active_consumer_tag,
messages_ram,
message_bytes_ram,
messages_dlx,
message_bytes_dlx
]).
-define(INFO_KEYS, [name, durable, auto_delete, arguments, pid, messages, messages_ready,
messages_unacknowledged, local_state, type] ++ ?STATISTICS_KEYS).
-define(RPC_TIMEOUT, 1000).
-define(START_CLUSTER_TIMEOUT, 5000).
-define(START_CLUSTER_RPC_TIMEOUT, 60_000). %% needs to be longer than START_CLUSTER_TIMEOUT
-define(TICK_TIMEOUT, 5000). %% the ra server tick time
-define(DELETE_TIMEOUT, 5000).
-define(ADD_MEMBER_TIMEOUT, 5000).
-define(SNAPSHOT_INTERVAL, 8192). %% the ra default is 4096
-define(UNLIMITED_PREFETCH_COUNT, 2000). %% something large for ra
%%----------- QQ policies ---------------------------------------------------
-rabbit_boot_step(
{?MODULE,
[{description, "QQ target group size policies. "
"target-group-size controls the targeted number of "
"member nodes for the queue. If set, RabbitMQ will try to "
"grow the queue members to the target size. "
"See module rabbit_queue_member_eval."},
{mfa, {rabbit_registry, register,
[policy_validator, <<"target-group-size">>, ?MODULE]}},
{mfa, {rabbit_registry, register,
[operator_policy_validator, <<"target-group-size">>, ?MODULE]}},
{mfa, {rabbit_registry, register,
[policy_merge_strategy, <<"target-group-size">>, ?MODULE]}},
{requires, rabbit_registry},
{enables, recovery}]}).
validate_policy(Args) ->
Count = proplists:get_value(<<"target-group-size">>, Args, none),
case is_integer(Count) andalso Count > 0 of
true -> ok;
false -> {error, "~tp is not a valid qq target count value", [Count]}
end.
merge_policy_value(<<"target-group-size">>, Val, OpVal) ->
max(Val, OpVal).
%%----------- rabbit_queue_type ---------------------------------------------
-spec is_enabled() -> boolean().
is_enabled() -> true.
-spec is_compatible(boolean(), boolean(), boolean()) -> boolean().
is_compatible(_Durable = true,
_Exclusive = false,
_AutoDelete = false) ->
true;
is_compatible(_, _, _) ->
false.
-spec init(amqqueue:amqqueue()) -> {ok, rabbit_fifo_client:state()}.
init(Q) when ?is_amqqueue(Q) ->
{ok, SoftLimit} = application:get_env(rabbit, quorum_commands_soft_limit),
{Name, _} = MaybeLeader = amqqueue:get_pid(Q),
Leader = case ra_leaderboard:lookup_leader(Name) of
undefined ->
%% leader from queue record will have to suffice
MaybeLeader;
LikelyLeader ->
LikelyLeader
end,
Nodes = get_nodes(Q),
%% Ensure the leader is listed first to increase likelihood of first
%% server tried is the one we want
Servers0 = [{Name, N} || N <- Nodes],
Servers = [Leader | lists:delete(Leader, Servers0)],
{ok, rabbit_fifo_client:init(Servers, SoftLimit)}.
-spec close(rabbit_fifo_client:state()) -> ok.
close(_State) ->
ok.
-spec update(amqqueue:amqqueue(), rabbit_fifo_client:state()) ->
rabbit_fifo_client:state().
update(Q, State) when ?amqqueue_is_quorum(Q) ->
%% QQ state maintains it's own updates
State.
-spec handle_event(rabbit_amqqueue:name(),
{amqqueue:ra_server_id(), any()},
rabbit_fifo_client:state()) ->
{ok, rabbit_fifo_client:state(), rabbit_queue_type:actions()} |
{eol, rabbit_queue_type:actions()} |
{protocol_error, Type :: atom(), Reason :: string(), Args :: term()}.
handle_event(QName, {From, Evt}, QState) ->
rabbit_fifo_client:handle_ra_event(QName, From, Evt, QState).
-spec declare(amqqueue:amqqueue(), node()) ->
{new | existing, amqqueue:amqqueue()} |
{protocol_error, Type :: atom(), Reason :: string(), Args :: term()}.
declare(Q, _Node) when ?amqqueue_is_quorum(Q) ->
case rabbit_queue_type_util:run_checks(
[fun rabbit_queue_type_util:check_auto_delete/1,
fun rabbit_queue_type_util:check_exclusive/1,
fun rabbit_queue_type_util:check_non_durable/1],
Q) of
ok ->
start_cluster(Q);
Err ->
Err
end.
start_cluster(Q) ->
QName = amqqueue:get_name(Q),
Durable = amqqueue:is_durable(Q),
AutoDelete = amqqueue:is_auto_delete(Q),
Arguments = amqqueue:get_arguments(Q),
Opts = amqqueue:get_options(Q),
ActingUser = maps:get(user, Opts, ?UNKNOWN_USER),
QuorumSize = get_default_quorum_initial_group_size(Arguments),
RaName = case qname_to_internal_name(QName) of
{ok, A} ->
A;
{error, {too_long, N}} ->
rabbit_data_coercion:to_atom(ra:new_uid(N))
end,
{LeaderNode, FollowerNodes} =
rabbit_queue_location:select_leader_and_followers(Q, QuorumSize),
LeaderId = {RaName, LeaderNode},
NewQ0 = amqqueue:set_pid(Q, LeaderId),
NewQ1 = amqqueue:set_type_state(NewQ0,
#{nodes => [LeaderNode | FollowerNodes]}),
rabbit_log:debug("Will start up to ~w replicas for quorum ~ts with leader on node '~ts'",
[QuorumSize, rabbit_misc:rs(QName), LeaderNode]),
case rabbit_amqqueue:internal_declare(NewQ1, false) of
{created, NewQ} ->
RaConfs = [make_ra_conf(NewQ, ServerId)
|| ServerId <- members(NewQ)],
%% khepri projections on remote nodes are eventually consistent
wait_for_projections(LeaderNode, QName),
try erpc_call(LeaderNode, ra, start_cluster,
[?RA_SYSTEM, RaConfs, ?START_CLUSTER_TIMEOUT],
?START_CLUSTER_RPC_TIMEOUT) of
{ok, _, _} ->
%% ensure the latest config is evaluated properly
%% even when running the machine version from 0
%% as earlier versions may not understand all the config
%% keys
%% TODO: handle error - what should be done if the
%% config cannot be updated
ok = rabbit_fifo_client:update_machine_state(LeaderId,
ra_machine_config(NewQ)),
notify_decorators(NewQ, startup),
rabbit_quorum_queue_periodic_membership_reconciliation:queue_created(NewQ),
rabbit_event:notify(queue_created,
[{name, QName},
{durable, Durable},
{auto_delete, AutoDelete},
{exclusive, false},
{type, amqqueue:get_type(Q)},
{arguments, Arguments},
{user_who_performed_action,
ActingUser}]),
{new, NewQ};
{error, Error} ->
declare_queue_error(Error, NewQ, LeaderNode, ActingUser)
catch
error:Error ->
declare_queue_error(Error, NewQ, LeaderNode, ActingUser)
end;
{existing, _} = Ex ->
Ex
end.
declare_queue_error(Error, Queue, Leader, ActingUser) ->
_ = rabbit_amqqueue:internal_delete(Queue, ActingUser),
{protocol_error, internal_error,
"Cannot declare quorum ~ts on node '~ts' with leader on node '~ts': ~255p",
[rabbit_misc:rs(amqqueue:get_name(Queue)), node(), Leader, Error]}.
ra_machine(Q) ->
{module, rabbit_fifo, ra_machine_config(Q)}.
ra_machine_config(Q) when ?is_amqqueue(Q) ->
QName = amqqueue:get_name(Q),
{Name, _} = amqqueue:get_pid(Q),
%% take the minimum value of the policy and the queue arg if present
MaxLength = args_policy_lookup(<<"max-length">>, fun min/2, Q),
OverflowBin = args_policy_lookup(<<"overflow">>, fun policyHasPrecedence/2, Q),
Overflow = overflow(OverflowBin, drop_head, QName),
MaxBytes = args_policy_lookup(<<"max-length-bytes">>, fun min/2, Q),
MaxMemoryLength = args_policy_lookup(<<"max-in-memory-length">>, fun min/2, Q),
MaxMemoryBytes = args_policy_lookup(<<"max-in-memory-bytes">>, fun min/2, Q),
DeliveryLimit = args_policy_lookup(<<"delivery-limit">>, fun min/2, Q),
Expires = args_policy_lookup(<<"expires">>, fun policyHasPrecedence/2, Q),
MsgTTL = args_policy_lookup(<<"message-ttl">>, fun min/2, Q),
#{name => Name,
queue_resource => QName,
dead_letter_handler => dead_letter_handler(Q, Overflow),
become_leader_handler => {?MODULE, become_leader, [QName]},
max_length => MaxLength,
max_bytes => MaxBytes,
max_in_memory_length => MaxMemoryLength,
max_in_memory_bytes => MaxMemoryBytes,
single_active_consumer_on => single_active_consumer_on(Q),
delivery_limit => DeliveryLimit,
overflow_strategy => Overflow,
created => erlang:system_time(millisecond),
expires => Expires,
msg_ttl => MsgTTL
}.
policyHasPrecedence(Policy, _QueueArg) ->
Policy.
queueArgHasPrecedence(_Policy, QueueArg) ->
QueueArg.
single_active_consumer_on(Q) ->
QArguments = amqqueue:get_arguments(Q),
case rabbit_misc:table_lookup(QArguments, <<"x-single-active-consumer">>) of
{bool, true} -> true;
_ -> false
end.
update_consumer_handler(QName, {ConsumerTag, ChPid}, Exclusive, AckRequired,
Prefetch, Active, ActivityStatus, Args) ->
catch local_or_remote_handler(ChPid, rabbit_quorum_queue, update_consumer,
[QName, ChPid, ConsumerTag, Exclusive,
AckRequired, Prefetch, Active,
ActivityStatus, Args]).
update_consumer(QName, ChPid, ConsumerTag, Exclusive, AckRequired, Prefetch,
Active, ActivityStatus, Args) ->
catch rabbit_core_metrics:consumer_updated(ChPid, ConsumerTag, Exclusive,
AckRequired,
QName, Prefetch, Active,
ActivityStatus, Args).
cancel_consumer_handler(QName, {ConsumerTag, ChPid}) ->
catch local_or_remote_handler(ChPid, rabbit_quorum_queue, cancel_consumer,
[QName, ChPid, ConsumerTag]).
cancel_consumer(QName, ChPid, ConsumerTag) ->
catch rabbit_core_metrics:consumer_deleted(ChPid, ConsumerTag, QName),
emit_consumer_deleted(ChPid, ConsumerTag, QName, ?INTERNAL_USER).
local_or_remote_handler(ChPid, Module, Function, Args) ->
Node = node(ChPid),
case Node == node() of
true ->
erlang:apply(Module, Function, Args);
false ->
%% this could potentially block for a while if the node is
%% in disconnected state or tcp buffers are full
erpc:cast(Node, Module, Function, Args)
end.
become_leader(QName, Name) ->
%% as this function is called synchronously when a ra node becomes leader
%% we need to ensure there is no chance of blocking as else the ra node
%% may not be able to establish its leadership
spawn(fun () -> become_leader0(QName, Name) end).
become_leader0(QName, Name) ->
Fun = fun (Q1) ->
amqqueue:set_state(
amqqueue:set_pid(Q1, {Name, node()}),
live)
end,
_ = rabbit_amqqueue:update(QName, Fun),
case rabbit_amqqueue:lookup(QName) of
{ok, Q0} when ?is_amqqueue(Q0) ->
Nodes = get_nodes(Q0),
_ = [_ = erpc_call(Node, ?MODULE, rpc_delete_metrics,
[QName], ?RPC_TIMEOUT)
|| Node <- Nodes, Node =/= node()],
ok;
_ ->
ok
end.
-spec all_replica_states() -> {node(), #{atom() => atom()}}.
all_replica_states() ->
Rows0 = ets:tab2list(ra_state),
Rows = lists:map(fun
({K, follower, promotable}) ->
{K, promotable};
({K, follower, non_voter}) ->
{K, non_voter};
({K, S, voter}) ->
{K, S};
(T) ->
T
end, Rows0),
{node(), maps:from_list(Rows)}.
-spec list_with_minimum_quorum() -> [amqqueue:amqqueue()].
list_with_minimum_quorum() ->
Queues = rabbit_amqqueue:list_local_quorum_queues(),
ReplicaStates = get_replica_states(rabbit_nodes:list_running()),
filter_quorum_critical(Queues, ReplicaStates, node()).
-spec list_with_local_promotable() -> [amqqueue:amqqueue()].
list_with_local_promotable() ->
Queues = rabbit_amqqueue:list_local_quorum_queues(),
#{node() := ReplicaStates} = get_replica_states([node()]),
filter_promotable(Queues, ReplicaStates).
-spec list_with_local_promotable_for_cli() -> [#{binary() => any()}].
list_with_local_promotable_for_cli() ->
Qs = list_with_local_promotable(),
lists:map(fun amqqueue:to_printable/1, Qs).
-spec get_replica_states([node()]) -> #{node() => replica_states()}.
get_replica_states(Nodes) ->
maps:from_list(
rabbit_misc:append_rpc_all_nodes(Nodes, ?MODULE, all_replica_states, [])).
-spec filter_promotable([amqqueue:amqqueue()], replica_states()) ->
[amqqueue:amqqueue()].
filter_promotable(Queues, ReplicaStates) ->
lists:filter(fun (Q) ->
{RaName, _Node} = amqqueue:get_pid(Q),
State = maps:get(RaName, ReplicaStates),
State == promotable
end, Queues).
-spec filter_quorum_critical([amqqueue:amqqueue()], #{node() => replica_states()}, node()) ->
[amqqueue:amqqueue()].
filter_quorum_critical(Queues, ReplicaStates, Self) ->
lists:filter(fun (Q) ->
MemberNodes = get_nodes(Q),
{Name, _Node} = amqqueue:get_pid(Q),
AllUp = lists:filter(fun (N) ->
case maps:get(N, ReplicaStates, undefined) of
#{Name := State}
when State =:= follower orelse
State =:= leader orelse
(State =:= promotable andalso N =:= Self) orelse
(State =:= non_voter andalso N =:= Self) ->
true;
_ -> false
end
end, MemberNodes),
MinQuorum = length(MemberNodes) div 2 + 1,
length(AllUp) =< MinQuorum
end, Queues).
capabilities() ->
#{unsupported_policies => [%% Classic policies
<<"max-priority">>, <<"queue-mode">>,
<<"single-active-consumer">>, <<"ha-mode">>, <<"ha-params">>,
<<"ha-sync-mode">>, <<"ha-promote-on-shutdown">>, <<"ha-promote-on-failure">>,
<<"queue-master-locator">>,
%% Stream policies
<<"max-age">>, <<"stream-max-segment-size-bytes">>, <<"initial-cluster-size">>],
queue_arguments => [<<"x-dead-letter-exchange">>, <<"x-dead-letter-routing-key">>,
<<"x-dead-letter-strategy">>, <<"x-expires">>, <<"x-max-length">>,
<<"x-max-length-bytes">>, <<"x-max-in-memory-length">>,
<<"x-max-in-memory-bytes">>, <<"x-overflow">>,
<<"x-single-active-consumer">>, <<"x-queue-type">>,
<<"x-quorum-initial-group-size">>, <<"x-delivery-limit">>,
<<"x-message-ttl">>, <<"x-queue-leader-locator">>],
consumer_arguments => [<<"x-priority">>],
server_named => false}.
rpc_delete_metrics(QName) ->
ets:delete(queue_coarse_metrics, QName),
ets:delete(queue_metrics, QName),
ok.
spawn_deleter(QName) ->
spawn(fun () ->
{ok, Q} = rabbit_amqqueue:lookup(QName),
delete(Q, false, false, <<"expired">>)
end).
spawn_notify_decorators(QName, Fun, Args) ->
%% run in ra process for now
catch notify_decorators(QName, Fun, Args).
handle_tick(QName,
#{config := #{name := Name},
num_active_consumers := NumConsumers,
num_checked_out := NumCheckedOut,
num_ready_messages := NumReadyMsgs,
num_messages := NumMessages,
enqueue_message_bytes := EnqueueBytes,
checkout_message_bytes := CheckoutBytes,
num_discarded := NumDiscarded,
num_discard_checked_out := NumDiscardedCheckedOut,
discard_message_bytes := DiscardBytes,
discard_checkout_message_bytes := DiscardCheckoutBytes,
smallest_raft_index := _} = Overview,
Nodes) ->
%% this makes calls to remote processes so cannot be run inside the
%% ra server
Self = self(),
spawn(
fun() ->
try
{ok, Q} = rabbit_amqqueue:lookup(QName),
Reductions = reductions(Name),
rabbit_core_metrics:queue_stats(QName, NumReadyMsgs,
NumCheckedOut, NumMessages,
Reductions),
Util = case NumConsumers of
0 -> 0;
_ -> rabbit_fifo:usage(Name)
end,
Keys = ?STATISTICS_KEYS -- [leader,
consumers,
messages_dlx,
message_bytes_dlx,
single_active_consumer_pid,
single_active_consumer_tag
],
{SacTag, SacPid} = maps:get(single_active_consumer_id,
Overview, {'', ''}),
MsgBytesDiscarded = DiscardBytes + DiscardCheckoutBytes,
MsgBytes = EnqueueBytes + CheckoutBytes + MsgBytesDiscarded,
Infos = [{consumers, NumConsumers},
{consumer_capacity, Util},
{consumer_utilisation, Util},
{message_bytes_ready, EnqueueBytes},
{message_bytes_unacknowledged, CheckoutBytes},
{message_bytes, MsgBytes},
{message_bytes_persistent, MsgBytes},
{messages_persistent, NumMessages},
{messages_dlx, NumDiscarded + NumDiscardedCheckedOut},
{message_bytes_dlx, MsgBytesDiscarded},
{single_active_consumer_tag, SacTag},
{single_active_consumer_pid, SacPid},
{leader, node()}
| info(Q, Keys)],
rabbit_core_metrics:queue_stats(QName, Infos),
ok = repair_leader_record(Q, Self),
ExpectedNodes = rabbit_nodes:list_members(),
case Nodes -- ExpectedNodes of
[] ->
ok;
Stale when length(ExpectedNodes) > 0 ->
%% rabbit_nodes:list_members/0 returns [] when there
%% is an error so we need to handle that case
rabbit_log:debug("~ts: stale nodes detected. Purging ~w",
[rabbit_misc:rs(QName), Stale]),
%% pipeline purge command
ok = ra:pipeline_command(amqqueue:get_pid(Q),
rabbit_fifo:make_purge_nodes(Stale)),
ok;
_ ->
ok
end
catch
_:Err ->
rabbit_log:debug("~ts: handle tick failed with ~p",
[rabbit_misc:rs(QName), Err]),
ok
end
end).
repair_leader_record(Q, Self) ->
Node = node(),
case amqqueue:get_pid(Q) of
{_, Node} ->
%% it's ok - we don't need to do anything
ok;
_ ->
QName = amqqueue:get_name(Q),
rabbit_log:debug("~ts: repairing leader record",
[rabbit_misc:rs(QName)]),
{_, Name} = erlang:process_info(Self, registered_name),
ok = become_leader0(QName, Name),
ok
end,
ok.
repair_amqqueue_nodes(VHost, QueueName) ->
QName = #resource{virtual_host = VHost, name = QueueName, kind = queue},
repair_amqqueue_nodes(QName).
-spec repair_amqqueue_nodes(rabbit_types:r('queue') | amqqueue:amqqueue()) ->
ok | repaired.
repair_amqqueue_nodes(QName = #resource{}) ->
{ok, Q0} = rabbit_amqqueue:lookup(QName),
repair_amqqueue_nodes(Q0);
repair_amqqueue_nodes(Q0) ->
QName = amqqueue:get_name(Q0),
Leader = amqqueue:get_pid(Q0),
{ok, Members, _} = ra:members(Leader),
RaNodes = [N || {_, N} <- Members],
#{nodes := Nodes} = amqqueue:get_type_state(Q0),
case lists:sort(RaNodes) =:= lists:sort(Nodes) of
true ->
%% up to date
ok;
false ->
%% update amqqueue record
Fun = fun (Q) ->
TS0 = amqqueue:get_type_state(Q),
TS = TS0#{nodes => RaNodes},
amqqueue:set_type_state(Q, TS)
end,
_ = rabbit_amqqueue:update(QName, Fun),
repaired
end.
reductions(Name) ->
try
{reductions, R} = process_info(whereis(Name), reductions),
R
catch
error:badarg ->
0
end.
is_recoverable(Q) when ?is_amqqueue(Q) and ?amqqueue_is_quorum(Q) ->
Node = node(),
Nodes = get_nodes(Q),
lists:member(Node, Nodes).
-spec recover(binary(), [amqqueue:amqqueue()]) ->
{[amqqueue:amqqueue()], [amqqueue:amqqueue()]}.
recover(_Vhost, Queues) ->
lists:foldl(
fun (Q0, {R0, F0}) ->
{Name, _} = amqqueue:get_pid(Q0),
ServerId = {Name, node()},
QName = amqqueue:get_name(Q0),
MutConf = make_mutable_config(Q0),
Res = case ra:restart_server(?RA_SYSTEM, ServerId, MutConf) of
ok ->
% queue was restarted, good
ok;
{error, Err1}
when Err1 == not_started orelse
Err1 == name_not_registered ->
rabbit_log:warning("Quorum queue recovery: configured member of ~ts was not found on this node. Starting member as a new one. "
"Context: ~s",
[rabbit_misc:rs(QName), Err1]),
% queue was never started on this node
% so needs to be started from scratch.
case start_server(make_ra_conf(Q0, ServerId)) of
ok -> ok;
Err2 ->
rabbit_log:warning("recover: quorum queue ~w could not"
" be started ~w", [Name, Err2]),
fail
end;
{error, {already_started, _}} ->
%% this is fine and can happen if a vhost crashes and performs
%% recovery whilst the ra application and servers are still
%% running
ok;
Err ->
%% catch all clause to avoid causing the vhost not to start
rabbit_log:warning("recover: quorum queue ~w could not be "
"restarted ~w", [Name, Err]),
fail
end,
%% we have to ensure the quorum queue is
%% present in the rabbit_queue table and not just in
%% rabbit_durable_queue
%% So many code paths are dependent on this.
ok = rabbit_db_queue:set_dirty(Q0),
Q = Q0,
case Res of
ok ->
{[Q | R0], F0};
fail ->
{R0, [Q | F0]}
end
end, {[], []}, Queues).
-spec stop(rabbit_types:vhost()) -> ok.
stop(VHost) ->
_ = [begin
Pid = amqqueue:get_pid(Q),
ra:stop_server(?RA_SYSTEM, Pid)
end || Q <- find_quorum_queues(VHost)],
ok.
-spec stop_server({atom(), node()}) -> ok | {error, term()}.
stop_server({_, _} = Ref) ->
ra:stop_server(?RA_SYSTEM, Ref).
-spec start_server(map()) -> ok | {error, term()}.
start_server(Conf) when is_map(Conf) ->
ra:start_server(?RA_SYSTEM, Conf).
-spec restart_server({atom(), node()}) -> ok | {error, term()}.
restart_server({_, _} = Ref) ->
ra:restart_server(?RA_SYSTEM, Ref).
-spec delete(amqqueue:amqqueue(),
boolean(), boolean(),
rabbit_types:username()) ->
{ok, QLen :: non_neg_integer()}.
delete(Q, IfUnused, IfEmpty, ActingUser) when ?amqqueue_is_quorum(Q) ->
{Name, _} = amqqueue:get_pid(Q),
QName = amqqueue:get_name(Q),
QNodes = get_nodes(Q),
{ok, ReadyMsgs, Consumers} = stat(Q),
IsEmpty = ReadyMsgs == 0,
IsUnused = Consumers == 0,
if IfEmpty and not(IsEmpty) -> {error, not_empty};
IfUnused and not(IsUnused) -> {error, in_use};
true ->
Timeout = ?DELETE_TIMEOUT,
Servers = [{Name, Node} || Node <- QNodes],
case ra:delete_cluster(Servers, Timeout) of
{ok, {_, LeaderNode} = Leader} ->
MRef = erlang:monitor(process, Leader),
receive
{'DOWN', MRef, process, _, _} ->
ok
after Timeout ->
erlang:demonitor(MRef, [flush]),
ok = force_delete_queue(Servers)
end,
notify_decorators(QName, shutdown),
ok = delete_queue_data(Q, ActingUser),
_ = erpc:call(LeaderNode, rabbit_core_metrics, queue_deleted, [QName],
?RPC_TIMEOUT),
{ok, ReadyMsgs};
{error, {no_more_servers_to_try, Errs}} ->
case lists:all(fun({{error, noproc}, _}) -> true;
(_) -> false
end, Errs) of
true ->
%% If all ra nodes were already down, the delete
%% has succeed
delete_queue_data(Q, ActingUser),
{ok, ReadyMsgs};
false ->
%% attempt forced deletion of all servers
rabbit_log:warning(
"Could not delete quorum '~ts', not enough nodes "
" online to reach a quorum: ~255p."
" Attempting force delete.",
[rabbit_misc:rs(QName), Errs]),
ok = force_delete_queue(Servers),
notify_decorators(QName, shutdown),
delete_queue_data(Q, ActingUser),
{ok, ReadyMsgs}
end
end
end.
force_delete_queue(Servers) ->
[begin
case catch(ra:force_delete_server(?RA_SYSTEM, S)) of
ok -> ok;
Err ->
rabbit_log:warning(
"Force delete of ~w failed with: ~w"
"This may require manual data clean up",
[S, Err]),
ok
end
end || S <- Servers],
ok.
delete_queue_data(Queue, ActingUser) ->
_ = rabbit_amqqueue:internal_delete(Queue, ActingUser),
ok.
delete_immediately(Queue) ->
_ = rabbit_amqqueue:internal_delete(Queue, ?INTERNAL_USER),
{ok, _} = ra:delete_cluster([amqqueue:get_pid(Queue)]),
rabbit_core_metrics:queue_deleted(amqqueue:get_name(Queue)),
ok.
settle(_QName, complete, CTag, MsgIds, QState) ->
rabbit_fifo_client:settle(quorum_ctag(CTag), MsgIds, QState);
settle(_QName, requeue, CTag, MsgIds, QState) ->
rabbit_fifo_client:return(quorum_ctag(CTag), MsgIds, QState);
settle(_QName, discard, CTag, MsgIds, QState) ->
rabbit_fifo_client:discard(quorum_ctag(CTag), MsgIds, QState).
credit_v1(_QName, CTag, Credit, Drain, QState) ->
rabbit_fifo_client:credit_v1(quorum_ctag(CTag), Credit, Drain, QState).
credit(_QName, CTag, DeliveryCount, Credit, Drain, Echo, QState) ->
rabbit_fifo_client:credit(quorum_ctag(CTag), DeliveryCount, Credit, Drain, Echo, QState).
-spec dequeue(rabbit_amqqueue:name(), NoAck :: boolean(), pid(),
rabbit_types:ctag(), rabbit_fifo_client:state()) ->
{empty, rabbit_fifo_client:state()} |
{ok, QLen :: non_neg_integer(), qmsg(), rabbit_fifo_client:state()} |
{error, term()}.
dequeue(QName, NoAck, _LimiterPid, CTag0, QState0) ->
CTag = quorum_ctag(CTag0),
Settlement = case NoAck of
true ->
settled;
false ->
unsettled
end,
rabbit_fifo_client:dequeue(QName, CTag, Settlement, QState0).
-spec consume(amqqueue:amqqueue(),
rabbit_queue_type:consume_spec(),
rabbit_fifo_client:state()) ->
{ok, rabbit_fifo_client:state(), rabbit_queue_type:actions()} |
{error, global_qos_not_supported_for_queue_type | timeout}.
consume(Q, #{limiter_active := true}, _State)
when ?amqqueue_is_quorum(Q) ->
{error, global_qos_not_supported_for_queue_type};
consume(Q, Spec, QState0) when ?amqqueue_is_quorum(Q) ->
#{no_ack := NoAck,
channel_pid := ChPid,
mode := Mode,
consumer_tag := ConsumerTag0,
exclusive_consume := ExclusiveConsume,
args := Args,
ok_msg := OkMsg,
acting_user := ActingUser} = Spec,
%% TODO: validate consumer arguments
%% currently quorum queues do not support any arguments
QName = amqqueue:get_name(Q),
maybe_send_reply(ChPid, OkMsg),
ConsumerTag = quorum_ctag(ConsumerTag0),
%% consumer info is used to describe the consumer properties
AckRequired = not NoAck,
{CreditMode, EffectivePrefetch, DeclaredPrefetch, ConsumerMeta0} =
case Mode of
{credited, C} ->
Meta = if C =:= credit_api_v1 ->
#{};
is_integer(C) ->
#{initial_delivery_count => C}
end,
{credited, 0, 0, Meta};
{simple_prefetch = M, Declared} ->
Effective = case Declared of
0 -> ?UNLIMITED_PREFETCH_COUNT;
_ -> Declared
end,
{M, Effective, Declared, #{}}
end,
ConsumerMeta = maps:merge(
ConsumerMeta0,
#{ack => AckRequired,
prefetch => DeclaredPrefetch,
args => Args,
username => ActingUser}),
{ok, QState} = rabbit_fifo_client:checkout(ConsumerTag, EffectivePrefetch,
CreditMode, ConsumerMeta,
QState0),
case single_active_consumer_on(Q) of
true ->
%% get the leader from state
case rabbit_fifo_client:query_single_active_consumer(QState) of
{ok, SacResult} ->
ActivityStatus = case SacResult of
{value, {ConsumerTag, ChPid}} ->
single_active;
_ ->
waiting
end,
rabbit_core_metrics:consumer_created(
ChPid, ConsumerTag, ExclusiveConsume,
AckRequired, QName,
DeclaredPrefetch, ActivityStatus == single_active, %% Active
ActivityStatus, Args),
emit_consumer_created(ChPid, ConsumerTag, ExclusiveConsume,
AckRequired, QName, DeclaredPrefetch,
Args, none, ActingUser),
{ok, QState};
{error, Error} ->
Error;
{timeout, _} ->
{error, timeout}
end;
false ->
rabbit_core_metrics:consumer_created(
ChPid, ConsumerTag, ExclusiveConsume,
AckRequired, QName,
DeclaredPrefetch, true, %% Active
up, Args),
emit_consumer_created(ChPid, ConsumerTag, ExclusiveConsume,
AckRequired, QName, DeclaredPrefetch,
Args, none, ActingUser),
{ok, QState}
end.
cancel(_Q, ConsumerTag, OkMsg, _ActingUser, State) ->
maybe_send_reply(self(), OkMsg),
rabbit_fifo_client:cancel_checkout(quorum_ctag(ConsumerTag), State).
emit_consumer_created(ChPid, CTag, Exclusive, AckRequired, QName, PrefetchCount, Args, Ref, ActingUser) ->
rabbit_event:notify(consumer_created,
[{consumer_tag, CTag},
{exclusive, Exclusive},
{ack_required, AckRequired},
{channel, ChPid},
{queue, QName},
{prefetch_count, PrefetchCount},
{arguments, Args},
{user_who_performed_action, ActingUser}],
Ref).
emit_consumer_deleted(ChPid, ConsumerTag, QName, ActingUser) ->
rabbit_event:notify(consumer_deleted,
[{consumer_tag, ConsumerTag},
{channel, ChPid},
{queue, QName},
{user_who_performed_action, ActingUser}]).
-spec stateless_deliver(amqqueue:ra_server_id(), rabbit_types:delivery()) -> 'ok'.
stateless_deliver(ServerId, Delivery) ->
ok = rabbit_fifo_client:untracked_enqueue([ServerId],
Delivery#delivery.message).
deliver0(QName, undefined, Msg, QState0) ->
case rabbit_fifo_client:enqueue(QName, Msg, QState0) of
{ok, _, _} = Res -> Res;
{reject_publish, State} ->
{ok, State, []}
end;
deliver0(QName, Correlation, Msg, QState0) ->
rabbit_fifo_client:enqueue(QName, Correlation,
Msg, QState0).
deliver(QSs, Msg0, Options) ->
Correlation = maps:get(correlation, Options, undefined),
Msg = mc:prepare(store, Msg0),
lists:foldl(
fun({Q, stateless}, {Qs, Actions}) ->
QRef = amqqueue:get_pid(Q),
ok = rabbit_fifo_client:untracked_enqueue([QRef], Msg),
{Qs, Actions};
({Q, S0}, {Qs, Actions}) ->
QName = amqqueue:get_name(Q),
case deliver0(QName, Correlation, Msg, S0) of
{reject_publish, S} ->
{[{Q, S} | Qs],
[{rejected, QName, [Correlation]} | Actions]};
{ok, S, As} ->
{[{Q, S} | Qs], As ++ Actions}
end
end, {[], []}, QSs).
state_info(S) ->
#{pending_raft_commands => rabbit_fifo_client:pending_size(S)}.
-spec infos(rabbit_types:r('queue')) -> rabbit_types:infos().
infos(QName) ->
infos(QName, ?STATISTICS_KEYS).
infos(QName, Keys) ->
case rabbit_amqqueue:lookup(QName) of
{ok, Q} ->
info(Q, Keys);
{error, not_found} ->
[]
end.
info(Q, all_keys) ->
info(Q, ?INFO_KEYS);
info(Q, Items) ->
lists:foldr(fun(totals, Acc) ->
i_totals(Q) ++ Acc;
(type_specific, Acc) ->
format(Q, #{}) ++ Acc;
(Item, Acc) ->
[{Item, i(Item, Q)} | Acc]
end, [], Items).
-spec stat(amqqueue:amqqueue()) ->
{'ok', non_neg_integer(), non_neg_integer()}.
stat(Q) when ?is_amqqueue(Q) ->
%% same short default timeout as in rabbit_fifo_client:stat/1
stat(Q, 250).
-spec stat(amqqueue:amqqueue(), non_neg_integer()) -> {'ok', non_neg_integer(), non_neg_integer()}.